Cách sử dụng hàm RANK trong Excel để xếp hạng nhanh chóng

Hàm RANK là một trong những hàm cơ bản được sử dụng phổ biến trong Excel để thống kê số liệu theo thứ hạng. Tuy nhiên không phải ai cũng biết cách sử dụng hàm này, nhất là đối với các bạn mới tìm hiểu và sử dụng công cụ tin học Excel. Bài viết dưới đây Dân Tài Chính sẽ hướng dẫn các bạn cách sử dụng hàm RANK một cách cụ thể và chi tiết nhất.

• Cách sử dụng hàm RANK
• Các ví dụ về hàm RANK
• Hàm RANK.AVG và hàm RANK.EQ
• Cách sử dụng hàm RANK sắp xếp có nhiều điều kiện

1.Cách sử dụng hàm RANK

Hàm RANK là hàm trả về thứ hạng của một ô dữ liệu trong danh sách, được dùng để xếp hạng dữ liệu theo thứ tự theo thứ tự từ cao đến thấp hoặc thấp đến cao tùy vào mục đích sử dụng. Hàm này sẽ giúp người sử dụng tiết kiệm được thời gian và công sức trong việc sắp xếp dữ liệu.

Mỗi hàm trong Excel đều được sử dụng theo một cú pháp nhất định và cú pháp của hàm Rank như sau

=RANK(number, ref, [order])

Giải thích

Rank: tên hàm, trong tiếng anh có nghĩa là thứ hạng

number: giá trị, dữ liệu cần được xếp hạng

ref: vùng dữ liệu, danh sách các giá trị để xếp hạng

order: đây là một chỉ số chỉ định thứ tự sắp xếp, kiểu sắp xếp: nếu thứ tự là 0 hoặc không điền, hàm RANK sẽ trả về danh sách được sắp xếp theo thứ tự giảm dần. Nếu thứ tự là 1, hàm RANK sẽ trả về một danh sách được sắp xếp theo thứ tự tăng dần.

2. Các ví dụ về hàm RANK

Để có thể hiểu rõ hơn về hàm này, hãy cùng thực hành cùng Dân Tài Chính nhé

Sử dụng hàm RANK xếp hạng từ thấp đến cao nhất

Để sắp xếp thứ tự điểm trung bình của các bạn trong lớp theo thứ tự từ thấp đến cao

Bước 1: Ở ô đầu tiên của cột xếp hạng ta điền công thức như sau

=RANK(B2; $B$2:$B$10; 1)

Giải thích

• B2: số liệu trong ô cần được xếp hạng
• $B$2:$B$10: vùng dữ liệu chưa giá trị B2, ta có thể cố định ô bằng cách chọn vùng từ B2 đến B10 rồi sau đó nhấn F4 hoặc Fn + F4
• 1: lệnh xếp hạng theo thứ tự từ thấp đến cao

Bước 2: Nhấn Enter

Bước 3: Xếp hạng các ô còn lại bằng cách kéo chuột từ ô C2 xuống đến ô C10. Theo bảng dướp đây, DTC 4 là học sinh có điểm trung bình xếp đầu tiên và DTC 9 là học sinh có điểm trung bình xếp hạng cuối.

Sử dụng hàm RANK xếp hạng từ cao xuống thấp

Để sắp xếp thứ tự điểm trung bình của các bạn trong lớp theo thứ tự từ cao xuống thấp

Bước 1: Ở ô đầu tiên của cột xếp hạng ta điền công thức như sau

=RANK(B2; $B$2:$B$10; 0)

Giải thích

• B2: số liệu trong ô cần được xếp hạng
• $B$2:$B$10: vùng dữ liệu chưa giá trị B2, ta có thể cố định ô bằng cách chọn vùng từ B2 đến B10 rồi sau đó nhấn F4 hoặc Fn + F4
• 0: lệnh xếp hạng theo thứ tự từ cao đến thấp

Bước 2: Nhấn Enter

Bước 3: Xếp hạng các ô còn lại bằng cách kéo chuột từ ô C2 xuống đến ô C10. Theo bảng dướp đây, DTC 4 là học sinh có điểm trung bình xếp cuối cùng và DTC 9 là học sinh có điểm trung bình xếp đầu tiên.

Hàm RANK có thể sắp xếp các số trùng lặp sẽ cùng một thứ hạng với nhau. Tuy nhiên điều này sẽ ảnh hưởng đến thứ hạng của các số phía sau. Trong ví dụ ở trên, khi sắp xếp theo thứ tự tăng giần, số 7 xuất hiện 2 lần và có thứ hạng là 4 thì số 8 sẽ có thứ hạng là 6 (không có số nào có thứ hạng 5)

Vậy làm thế nào để sắp xếp các số liệu theo thứ tự mà không bị ngắt quãng bởi các số liệu giống nhau? 

Đối với cách sắp xếp theo thứ tự tăng dần, ta có thể dùng hàm như sau

=SUMPRODUCT((B2>=$B$2:$B$10)/COUNTIF($B$2:$B$10; $B$2:$B$10))

Vị trí điểm 7 đã có số hạng là 4, vị trí điểm 8 có số hạng là 5

Ngược lại, đối với cách sắp xếp theo thứ tự giảm dần, ta có thể dùng hàm như sau

=SUMPRODUCT((B2<=$B$2:$B$10)/COUNTIF($B$2:$B$10; $B$2:$B$10))

Vị trí điểm 8 đã có số hạng là 3, vị trí điểm 7 có số hạng là 4

Xem thêm: Cách sử dụng hàm Sumproduct

3. Hàm RANK.AVG và hàm RANK.EQ

Hiện giờ hàm RANK vẫn được sử dụng tuy nhiên đã dần được thay thế bởi một số hàm mới có độ chính xác cao và có tên gọi phản ánh rõ các công dụng của chúng là hàm RANK.AVG và RANK.EQ (từ phiên bản Excel 2010 trở đi). Các hàm này đều có công thức tương tự như nhau nhưng kết quả thu được có sự khác biệt

Bảng trên đây thể hiện kết quả, hàm RANK và RANK.EQ cho kết quả giống nhau

Hàm RANK.AVG (Average) có nghĩa là thứ hạng trung bình, nghĩa là nếu có số hạng ngang nhau thì sẽ xếp hạng trung bình cho 2 người đó.

Hàm RANK.EQ (Equal) sẽ xếp đồng hạng mà không tính trung bình hạng, nghĩa là nếu có 2 người cùng thứ hạng thì sẽ xếp vào thứ hạng làm tròn, chứ không phải thứ hạng lẻ.

4. Cách sử dụng hàm RANK sắp xếp có nhiều điều kiện

Dữ liệu sẽ được sắp xếp theo điều kiện trước, sau. Công thức xếp hạng của các điều kiện sẽ phụ thuộc vào thứ hạng của điều kiện trước đó. 

Đối với ví dụ dưới đây xếp hạng các học sinh theo điểm trung bình tổng các môn, nếu đồng hạng thì xét ưu tiên theo thứ tự Toán => Lý => Hóa.

Ta có thể thấy với dòng 7 và dòng 10 đều có điểm trung bình là 7.00 đồng xếp hạng 6, ta cần phải xem thêm các điều kiện ưu tiên khác.

Bước 1: Xét ưu tiên môn Toán khi điểm trung bình bằng nhau. Ta sử dụng công thức

L4=IF(COUNTIF($E$4:$E$13,E4)>1, RANK.EQ(B4,$B$4:$B$13,1), 0)

Kéo chuột từ ô L4 xuống L13

Bước 2: Khi điểm môn Toán bằng nhau, ta tiếp tục xếp hạng môn Lý (xếp hạng theo thứ tự ưu tiên, có phụ thuộc vào thứ tự ở trước đó). Ta sử dụng công thức sau

M4 =IF(AND(L4>0,COUNTIF(L$4:L$13,L4)>1), RANK.EQ(C4,C$4:C$13,1), 0)

Kéo chuột từ ô M4 xuống M13

Giải thích

• L4>0: Xét các điểm trung bình môn Toán có giá trị trùng với nhau
• COUNTIF(L$4:L$13,L4)>1: Xét với trường hợp xếp hạng ưu tiên môn Toán có xếp hạng giống nhau (đếm số kết quả xếp hạng môn Toán, nếu lớn hơn 1 tức là có sự đồng hạng với nhau).
• AND(L4>0,COUNTIF(L$4:L$13,L4)>1): Khi thỏa mãn đồng thời cả 2 điều kiện trên thì mới xét đến trường hợp ưu tiên môn Lý
• RANK.EQ(C4,C$4:C$13,1): Xếp hạng điểm môn Lý theo thứ tự tăng dần.

Bước 3: Khi xếp hạng môn Toán và môn Lý bằng nhau, ta xét đến ưu tiên môn Hóa

N4=IF(AND(M4>0,COUNTIF(M$4:M$13,M4)>1),RANK.EQ(D4,D$4:D$13,1),0)

• M4>0: khi đã xét các điểm số trùng môn Toán, xét thêm môn Lý có thứ hạng nào trùng hay không (khác 0).
• COUNTIF(M$4:M$13,M4)>1: Xét với trường hợp ưu tiên xếp hạng môn Lý giống nhau.
• AND(M4>0,COUNTIF(M$4:M$13,M4)>1): khi cả 2 điều kiện trên được thỏa mãn thì mới xét đến điểm ưu tiên môn Hóa
• AND(M4>0,COUNTIF(M$4:M$13,M4)>1): xếp hạng điểm môn Hóa theo thứ tự từ thấp đến cao.

Bước 4: Tính điểm trung bình dựa trên điểm ưu tiên của các điều kiện

)4= E4+L4/1000 + M4/10000 + N4/100000

Bước 5: Dựa trên điểm trung bình mới, sử dụng hàm RANK để sắp xếp lại theo thứ tự giảm dần

=RANK.EQ(O4, $O$4:$O$13, 0)

Ta có thể thấy thứ tự xếp hạng của các học sinh đã được thay đổi theo thứ tự ưu tiên.

Trên đây là một số kiến thức về hàm RANK trong Excel. Mong rằng bài viết này sẽ giúp ích cho các bạn trong việc sử dụng các hàm và tiết kiệm thời gian cho mình.

5/5 - (1 bình chọn)

The post Cách sử dụng hàm RANK trong Excel để xếp hạng nhanh chóng appeared first on Dân tài chính.

source https://www.dantaichinh.com/cach-su-dung-ham-rank-trong-excel